Hola
Antes de nada decir que acabo de empezar con esto de los micrcontroladores y mis conocimientos son nulos, dicho esto:
Llevo 3 horas intentando hacer funcionar el siguiente ejemplo nº 8 que me vino incluido en el CD Laboratorio USB-PIC'SCHOOL para PIC's, con entorno de desarrollo MPLAB-IDE original de Microchip (PICkit 2)
El caso es que intento cargar con el MPLAB-IDE el programa, hasta aqui todo bien, pues aparentemente no me da ningun error, creo que meto la pata en las conexiones del entrenador, el ejemplo que viene en el cd es el siguiente y creo que no falta nada:
;
; EJEMPLO 8
; Autor: Mikel Etxebarria
; (c) Ingeniería de Microsistemas Programados S.L.
; www.microcontroladores.com
; Bilbao 2010
;
;Entradas/salidas digitales: Juego de luces, otra temporización.
;
;Se desea realiza una rotación secuencial en el encendido de cada led contectados a la
;puerta B del laboratorio PIC'School. Si RA0 = 0, la rotación será de derecha a izquierda
;y viceversa. Cada led permanece encendido 0.25 segundos (250 mS)
List p=16F886 ;Tipo de procesador
include "P16F886.INC" ;Definiciones de registros internos
#define Fosc 4000000 ;Velocidad de trabajo
;Ajusta los valores de las palabras de configuración durante el ensamblado.Los bits no empleados
;adquieren el valor por defecto.Estos y otros valores se pueden modificar según las necesidades
__config _CONFIG1, _LVP_OFF&_PWRTE_ON&_WDT_OFF&_EC_OSC&_FCMEN_OFF ;Palabra 1 de configuración
__config _CONFIG2, _WRT_OFF&_BOR40V ;Palabra 2 de configuración
Contador equ 0x20 ;Variable para la temporización
MSE_Delay_V equ 0x73 ;Variables (3) empleadas por las macros de temporización
org 0x00
goto Inicio ;Vector de reset
org 0x05
include "MSE_Delay.inc" ;Incluir rutinas de temporización
Inicio clrf PORTB ;Borra los latch de salida
bsf STATUS,RP0
bsf STATUS,RP1 ;Selecciona banco 3
clrf ANSEL ;Puerta A digital
clrf ANSELH ;Puerta B digital
bcf STATUS,RP1 ;Selecciona banco 1
clrf TRISB ;RB7:RB0 se configuran como salida
movlw b'00111111'
movwf TRISA ;RA5:RA0 se configuran como entrada
bcf STATUS,RP0 ;Selecciona banco 0
bsf STATUS,C ;Activa el carry
Loop
Delay 250 Milis ;Temporiza 250mS
btfsc PORTA,0 ;Está a 0 RA0 ??
goto A_Dcha ;No, rotación a derecha
A_Izda rlf PORTB,F ;Si, rotación a izquierda
goto Loop
A_Dcha rrf PORTB,F ;Rotación a derecha
goto Loop
end ;Fin del programa fuente
En el manual de los ejemplos me dice de conectar los LEDS S0-S7 a las lineas RB0-RB7 de salida y el interuptor E0 conectarlo al RAO y si no me equivoco eso he hecho ¿no? o si? XD aqui las pruebas del delito:
Saludos