El Timer 1 del 12F629 no me cuenta

[BrunoF]

Buenas...

Voy a recurrir al foro ya que no me está saliendo esto que parece tan básico:
La idea es contar los pulsos que ingresen por el pin GP5 mediante el TImer1.

Estimulo el Pin GP5 desde el MPLAB, pero no me incrementa el  registro TMR1L!!!

¿Qué estoy configurando mal?

Acá va el trozo de programa involucrado:

Código: ASM

1. ;/////////////////////
2.                 ORG             0x000                   ;Vector Power up/Reset
3. ;/////////////////////
4.  
5.                 call    0x3FE                   ;Llamar a subrutina de calibracion de oscilador interno
6.                 movwf   OSCCAL                  ;Y guardar el valor en el registro de calibracion
7.                 bcf     STATUS, RP0             ;volver al banco 0
8.                 goto    INICIO                  ;Saltar a INICIO de programa
9.  
10. ;/////////////////////
11.                 ORG             0x004                   ;Vector de Interrupciones.
12. ;/////////////////////
13.                 goto    ISR
14.  
15. INICIO
16.                 clrf    INTCON
17.                 bsf             STATUS,RP0              ;banco 1
18.                 bcf             DataS
19.                 bcf             ClockS
20.                 bcf             StrobeS
21.                 bsf             TRISIO, 3
22.                 bcf             TRISIO, 4
23.                 bsf             TRISIO, 5               ;Contador Timer1
24.                 bcf             STATUS,RP0              ;banco 0
25.                
26.                 clrf    GPIO                    ;Limpiar latches
27.  
28.                 movlw   PrimeraRAM              ;w = primera posicion RAM válida para este uC
29.                 call    LIMPIARRAM              ;Limpiar toda la RAM banco 0
30.  
31.                 incf    Periodo, F              ;inicializar Periodo = 1
32.                
33.                 ;Config TIMER0
34.                 bsf             STATUS, RP0                     ;banco 1
35.                 bcf             OPTION_REG, T0CS        ;contador interno
36.                 bcf             OPTION_REG, T0SE        ;Incrementar en flanco bajo a alto
37.                 bcf             OPTION_REG, PSA         ;Preescaler asociado al Timer0
38.                 bcf             OPTION_REG, PS2         ;Preescaler 1:8
39.                 bsf             OPTION_REG, PS1         ;Preescaler 1:8
40.                 bcf             OPTION_REG, PS0         ;Preescaler 1:8
41.                 bcf             STATUS, RP0                     ;banco 0
42.                
43.                 call    ResetTimer0                     ;setear valores iniciales de los registros del Timer1
44.  
45.                 ;Config TIMER1
46.                 clrf    TMR1L                           ;limpiar contadores timer
47.                 clrf    TMR1H
48.  
49.                 bcf     T1CON, TMR1GE           ;Activar Timer1  (6)
50.                 bcf     T1CON, T1CKPS1          ; Preescaler 1:1 (5)
51.                 bcf     T1CON, T1CKPS0          ; Preescaler 1:1 (4)
52.                 bcf     T1CON, T1OSCEN          ;oscilador LP apagado (3)
53.                 bsf             T1CON, NOT_T1SYNC       ;No sincronizar pulso externo con clock interno (2)
54.                 bsf             T1CON, TMR1CS           ;Contador asociado a pulsos externos en GP5  (1)
55.                 bsf     T1CON, TMR1ON           ;Encender Timer1 (0)
56.  
57.                 ;Config INTERRUPCIONES
58.                 bcf             INTCON, T0IF            ;Limpiar flag Timer0
59.                 bsf             INTCON, T0IE            ;activar interrupcion Timer0
60.  
61.                 ;Interr Globales
62.                 bsf             INTCON, GIE                     ;Activar interrupciones globales
63.  
64.                 goto    $
65.  
66. ;//////////////////////////////////////
67. ;//            ISR                   //
68. ;//////////////////////////////////////
69.  
70. ISR            
71.                 nop            ;aca ya no me incrementa

Gracias!!

[maunix]

Bruno, ¿y has podido ver el estado del TRISIO?  Te pregunto porque yo intenté probar tu software y ni siquiera eso me pone bien 

Respecto al llamado al registro de calibración, creo que sería CALL 0x3FF , aunque eso solo afectará que ejecutará una instrucción más si es que no hay código en 0x3FE.

[BrunoF]

Hola Mauricio!!!

Joer! Tenés razón.

Pero debo estar muy loco u olvidado del tema porque si pongo por ejeeeemplo:

bsf  TRISIO, 5 = bsf   0x85, 5 pero como solo se permiten 7 bits pal' registro quedaría bsf 0x05, 5 = bsf GPIO, 5.

Entonces, ¿que ha pasado aquí?

Ya. He probado con bsf GPIO, 5 y tampoco funciona. También cargandole un literal y moviendolo al GPIO.

¡No logro setear los pines! 

¡Por favor! Si hay algo que se cae de maduro y lo saben, diganlo! que no les de verguenza, eh??

Será el MPLAB? Estoy usando la 7.60

Con respecto a la calibracion:

Código: ASM

1. ;/////////////////////
2.                 ORG             0x3FE                   ;Vector Calibracion - 1
3. ;/////////////////////
4.  
5.                 bsf     STATUS, RP0             ;banco 1
6.                 RETLW   0x80                    ;Valor de calibracion(@ 4Mhz)

tuve que ponerlo asi, sino se me superponia con el vector de interrupcion y ya no queria andar haciendo artilugios.

Gracias Mauricio! Me voy hasta el shop a comprar el látigo pa' disciplinar a este MPLAB SIM...

[maunix]

Como costumbre, apagar los comparadores cuando no los usas. 


      movlw      0x07
      movwf      CMCON


pero esto no debiera afectar a tu software.  Tampoco lo pude simular y a mi parecer es un 'gran bug' en el simulador que no estaba presente antes porque yo lo intenté simular con un 12f675 (que yo si los he usado) y realmente tampoco funciona.

Lo que sí afecta a tu software es que de seguro no tienes agregada la configuración los fuses pic, lo cual es importante a la hora de simular. 
Pensá que el setear los 'configuration bits' es solo para el uso de un programador bajo el IDE pero no para la simulación.  En la simulación lee el .HEX

La línea mágica que te hace falta es


   __config   _INTRC_OSC_NOCLKOUT & _WDT_OFF & _MCLRE_OFF & _PWRTE_ON & _CPD_ON & _CP_ON & _BODEN_OFF


 


Con respecto a lo del registro de calibración, viene de fábrica por lo cual no debieras tocar nada... de hecho el GTP-USB+ te avisa si queres sobreescribir este valor o usar uno propuesto por vos.  Ahora si quieres usar uno propuesto por vos yo haría diferente, pero más que nada por gustos y por un tema de tener todo acomodado.  Lo que es calibración (editar la línea 0x3FF) ... como te comenté antes, ni lo tocaría salvo que realmente lo necesites.


      org  0x000

      call      0x3FFF
      bsf       STATUS,RPO
      movwf     OSCCAL


      org  0x3FF

      retlw     0x80

[BrunoF]

Que mal! Entonces voy a tener que buscar alguna versión anterior del MPLAB...

Gracias por lo de los comparadores. Había olvidado que tenía ADC este PIC(hace como 2 años que los tengo "tirados").

Con respecto a los fuses, los tenía puestos. no los puse porque pensé que no tenían relevancia o eran redundantes para el problema presente.

Código: ASM

1. LIST            p=12F629
2.                 processor       PIC12F629
3.                 #include        "P12F629.INC"
4.                 __CONFIG        _CP_OFF & _PWRTE_ON & _WDT_OFF & _XT_OSC & _BODEN_OFF & _MCLRE_OFF & _INTRC_OSC_NOCLKOUT
5.  
6.                 ERRORLEVEL      -302
7.  
8. #DEFINE LSB                     .0
9. #DEFINE _C                      STATUS, C
10.  
11. ;Datos PIC(12F629)
12. #DEFINE PrimeraRAM      0x20
13. #DEFINE UltimaRAM       0x5F
14.  
15. #DEFINE Cantidad        .4                                                                                                              ;Seleccione cantidad sensores por vuelta
16.  
17. #DEFINE Refrescos       .4
18.  
19. ;Config Maximas RPM
20. #DEFINE Max_RPM         .5000                                                                                                   ;(RPM)
21. #DEFINE Max_Puls        (Max_RPM / .60)                                                                                 ;Interno
22. #DEFINE TiempoBase      .1000                                                                                                   ;(uS)
23.  
24. #DEFINE MultipRPM       ((Refrescos * Max_RPM)/(Max_Puls * Cantidad))                   ;Calculo interno. No tocar.
25.  
26. #DEFINE RefCada         (.1000000 / TiempoBase / Refrescos)                                             ;Cantidad de interrupciones que deben suceder para que se refresquen los RPMs
27.  
28. ;Config memoria PWM
29. #DEFINE CantidadPWM     .56
30. #DEFINE PrimerPWM       UltimaRAM - CantidadPWM
31. #DEFINE UltimoPWM       PrimerPWM + CantidadPWM - 1
32.  
33. #DEFINE Max_Steps       (CantidadPWM * .256 - 1)        
34. #DEFINE PreTMR          (.256 - (TiempoBase / .8) + 1)
35.  
36. ;Checkeo Errores configuración
37.         if CantidadPWM == 0
38.                 error "Debe haber al menos 1 PWM!"
39.         endif
40.  
41.         if (UltimoPWM > UltimaRAM)
42.                 error "Posicion inválida de memoria!"
43.         endif
44.  
45. ;Asignacion de pines
46. #DEFINE DataS           GPIO, 0
47. #DEFINE ClockS          GPIO, 1
48. #DEFINE StrobeS         GPIO, 2
49.  
50. ;Variables
51.         CBLOCK  PrimeraRAM
52.         Periodo
53.         RPMHigh
54.         RPMLow
55.         Pulsos
56.         ContRefresco
57.  
58.         AARGB0
59.         AARGB1
60.         AARGB2
61.         AARGB3
62.        
63.         BARGB0
64.         BARGB1
65.        
66.         TEMPB0
67.         TEMPB1
68.        
69.         REMB0
70.         REMB1
71.        
72.         TEMP
73.        
74.         LOOPCOUNT
75.  
76.         ENDC
77.  
78.  
79. ;//////////////////////////////////////////////////////////////////////////////////////////////
80. ;//                                                                     PROGRAMA                                                                                                 //
81. ;//////////////////////////////////////////////////////////////////////////////////////////////
82.  
83. ;/////////////////////
84.                 ORG             0x000                   ;Vector Power up/Reset
85. ;/////////////////////
86.  
87.                 call    0x3FE                   ;Llamar a subrutina de calibracion de oscilador interno
88.                 ...
89.                 ...
90.                 ...

Y con respecto a la calibración, pues ya lo perdí hace rato al valor de fábrica. El software que usaba antes(IC-PROG) no era muy intuitivo de usar, y allí fueron los "factory default values".

Gracias Mauricio! Pensé que estaba loco. Ahora que parece ser un "bug", me quedo más tranquilo.

Un abrazo.

[maunix]

Que mal! Entonces voy a tener que buscar alguna versión anterior del MPLAB...

Bruno, te aclaro que yo probé y me funcionó en el MPLAB 7.60.

[BrunoF]

Te funcionó???

¿Entonces es solamente mi MPLAB? :O :O

[maunix]

Te funcionó???

¿Entonces es solamente mi MPLAB? :O :O

Hagamos una cosa, ¿podes subir el .asm en un .zip?  Porque otra vez copiar y editar el tuyo no quiero 

Es que cuando copio de la pantalla me aparecen todos unos # en cada línea lo cual es tedioso borrar 

Y capaz que los 4 Gigas de Ram le hagan mal al MPLAB... algo así como "Empacho de Memoria"

[BrunoF]

Comprendo. Mea Culpa. Debería haber adjuntado el archivo desde el principio.

Me anda muy mal la coneccion. No logro adjuntar el archivo...en cuanto pueda lo adjunto.

Te comento que hice un downgrade a la versión 7.31 y sigue sin funcionarme...

¿Te parece que los 4G de RAM pueden influír? Me parece poco probable...pero con guindous nunca se sabe...

:S

La imágen:




Gracias!

[maunix]

¿Te parece que los 4G de RAM pueden influír? Me parece poco probable...pero con guindous nunca se sabe...

No, de ninguna manera, era un chiste (muy malo por cierto) 

Acabo de ver algo que no había notado, algo que yo no tenía en mi config y vos si.

__CONFIG    _CP_OFF & _PWRTE_ON & _WDT_OFF & _XT_OSC & _BODEN_OFF & _MCLRE_OFF & _INTRC_OSC_NOCLKOUT


Es el incluir _XT_OSC lo que opino que no debes hacer.

Sencillamente no hace falta y justamente le estas diciendo al config que usarás clock externo, por ende los pines GP4 y GP5 no están disponibles para el usuario 

Creo que ahí esta el problema  

[BrunoF]

¡¡¡I N C R E Í B L E!!!

ERA ESO!!!!!

Muchísimas gracias Mauricio! Consideraré este como un regalo más de cumpleaños

Un abrazo!!!

[maunix]

¡¡¡I N C R E Í B L E!!!

ERA ESO!!!!!

Muchísimas gracias Mauricio! Consideraré este como un regalo más de cumpleaños

Jeje, viste, a veces un pequeño error se manifiesta como una falla grave 

Me imagino los recuerdos que habrás tenido para las madres de los programadores del MPLAB y MPSIM  y todos ellos inocentes y libres de culpa

¡¡Me alegro que te funcione en el día de tu cumpleaños!!  Yo te pensaba cobrar unos 200 dspic 33F y un ron para Manolo (nos tiene amenazados si no hacemos esto) pero ahora, me hiciste dar cargo de conciencia así que va como regalo de cumpleaños 

[BrunoF]

Si. Realmente impresionante.

Pero no debería igualmente haberse comportado así el Simulador, ¿o si?

En fin, lo importante es que ahora me funciona! y gracias a vos! Creo que jamás hubiese encontrado por mi cuenta ese detalle...antes hubiese viajado hasta Microchip a putear personalmente...

¡¡Me alegro que te funcione en el día de tu cumpleaños!!  Yo te pensaba cobrar unos 200 dspic 33F y un ron para Manolo (nos tiene amenazados si no hacemos esto) pero ahora, me hiciste dar cargo de conciencia así que va como regalo de cumpleaños 

Jaja! Zafé. Lo malo que solamente te voy a poder "manguear" consejos gratis una vez al año entonces...

Un abrazo.

[maunix]

Pero no debería igualmente haberse comportado así el Simulador, ¿o si?

Yo creo que así como está el simulador, está bien.  Es decir, en un hardware 'verídico' tampoco te hubiera funcionado porque en esos pines hubiera esperado que le cuelgues el clock y el hardware interno no haría más que habilitar la circuitería para el oscilador, por ende no serían pines de E/S.

También pasa que por ejemplo en los micros 18F que tienes el timer1 o timer3 en modo 16 bits, puedes seleccionar que se lean todo de una sola instrucción.  Ahora bien, el estado del registro TMR1H se actualiza solamente cuando se lee el TMR1L y no antes.  Es así como funciona el hardware y así como funciona el simulador. 

En fin, lo importante es que ahora me funciona! y gracias a vos! Creo que jamás hubiese encontrado por mi cuenta ese detalle...antes hubiese viajado hasta Microchip a putear personalmente...

Yo creo que lo hubieras encontrado, solo que tal vez te hubiera demorado algo más de tiempo.  Te considero una persona muy observadora.  Te pasó lo que a todos nos pasa alguna vez , estar encerrado en el problema, y no ver que es 'otra cosa' y luego viene uno de afuera y te dice "ey, tenes apagada la fuente de alimentación" 
Eso pasa a menudo y no estoy exento de eso, simplemente que esta vez yo fui 'el que venía de afuera'.

Jaja! Zafé. Lo malo que solamente te voy a poder "manguear" consejos gratis una vez al año entonces...

Jaja, no , no es así, era solo un chistecito.  No tengo dramas en dar consejos gratis (si es que sé la respuesta) y si necesitas ayuda en algo te podré ayudar por aquí.  y si es un tema 'delicado' laboral o personal puede ser por mensaje privado o mail